Sports Illustrated for Kids - Awesome Athletes!/Sports Illustrated for Kids - Awesome Athletes!.iso/iv.dir/00007_text box scripts.ls

Text File | 1996-04-19 | 6.8 KB | 199 lines

on SetQuestionTextBox _hilite
  global givTextRegColor, givTextHiliteColor, givAthleteNameList, givGuestStarList, givState, givQUESTIONTEXTBACKSPRITE, givTextHiliteBlue
  MessagePut("setting question text box...")
  set the foreColor of field "QuestionTextBox" to givTextRegColor
  set P to EMPTY
  if the activeMonitor of givState = 1 then
    if the selectType of givState = #topic then
      set P to "T" & the topicNum of givState
    else
      set P to "I" & the lastAthlete of givState
    end if
  else
    if the activeMonitor of givState = 2 then
      set P to "IN"
    else
      if the activeMonitor of givState = 3 then
        if (the mode of givState = #play) and (count(the editList of givState) > 0) then
          set P to "ED"
        else
          set P to "TR"
        end if
      else
        if the activeMonitor of givState = 4 then
          set P to "AD"
        else
          if the activeMonitor of givState = 5 then
            set P to "EN"
          else
            if the activeMonitor of givState = 6 then
              set P to "AV" & the lastAthlete of givState
            end if
          end if
        end if
      end if
    end if
  end if
  if the activeMonitor of givState = 6 then
    set the castNum of sprite givQUESTIONTEXTBACKSPRITE to the number of cast "AV.pct"
  else
    set the castNum of sprite givQUESTIONTEXTBACKSPRITE to the number of cast (P & ".pct")
  end if
  if P = "ED" then
    set the text of field "QuestionTextBox" to the text of cast "EditListBuild"
    set the foreColor of field "QuestionTextBox" to givTextHiliteBlue
  else
    set the text of field "QuestionTextBox" to the text of cast P
    if not voidp(_hilite) and (_hilite = 1) then
      SetQuestionTextBoxHilite()
    end if
  end if
  updateStage()
end

on SetQuestionTextBoxHilite num
  global givTextRegColor, givTextHiliteColor, givState
  if (the mode of givState = #play) and (the activeMonitor of givState = 3) then
    nothing()
    exit
  end if
  if (count(the questionSelectList of givState) > 0) and voidp(num) then
    DisplayFromList()
    exit
  end if
  set the foreColor of field "QuestionTextBox" to givTextRegColor
  if voidp(num) then
    set the foreColor of line GetMonitorPtr(givState, the activeMonitor of givState) of field "QuestionTextBox" to givTextHiliteColor
  else
    MessagePut("set to " & num)
    set the foreColor of line num of field "QuestionTextBox" to givTextHiliteColor
  end if
end

on SetQuestionClipFromTextBox lineNum
  global givState
  MessagePut("setting clip to match text box with line num:" && lineNum)
  set lis to GetMonitorListByNumber(the activeMonitor of givState)
  set newClip to getAt(lis, lineNum)
  MessagePut("NewClip:" && newClip)
  if count(the questionSelectList of givState) < 1 then
    SetMonitorPtr(givState, the activeMonitor of givState, lineNum)
  else
    SetMonitorPtr(givState, the activeMonitor of givState, getAt(the questionSelectList of givState, 1))
  end if
  PlaySoundWait("CLIK2.AIF")
  DisplayMonitor(the activeMonitor of givState)
  if the activeMonitor of givState = 1 then
    SetAthleteFromMonitor(givState)
  end if
end

on AddToSelectList mLine
  global givState
  if mLine < the number of lines in field "QuestionTextBox" then
    MessagePut("entering AddToSelectList with list = " & the questionSelectList of givState & " sent line " & mLine)
    set found to 0
    repeat with I = 1 to count(the questionSelectList of givState)
      if mLine = getAt(the questionSelectList of givState, I) then
        set found to I
      end if
    end repeat
    if found = 0 then
      append(the questionSelectList of givState, mLine)
    else
      deleteAt(the questionSelectList of givState, found)
    end if
    DisplayFromList()
  end if
end

on DisplayFromList
  global givState, givTextRegColor, givTextHiliteColor
  MessagePut("display from question select list...")
  set the foreColor of cast "QuestionTextBox" to givTextRegColor
  repeat with I = 1 to the number of lines in field "QuestionTextBox" - 1
    set j to getPos(the questionSelectList of givState, I)
    if j = 0 then
      if char 2 of line I of field "QuestionTextBox" = ":" then
        put "--" into char 1 to 2 of line I of field "QuestionTextBox"
      else
        if char 3 of line I of field "QuestionTextBox" = ":" then
          put "--" into char 1 to 3 of line I of field "QuestionTextBox"
        else
          nothing()
        end if
      end if
      next repeat
    end if
    if j < 10 then
      if char 3 of line I of field "QuestionTextBox" = ":" then
        delete char 1 of line I of field "QuestionTextBox"
        put string(j) & ":" into char 1 to 2 of line I of field "QuestionTextBox"
      else
        put string(j) & ":" into char 1 to 2 of line I of field "QuestionTextBox"
      end if
    else
      if char 3 of line I of field "QuestionTextBox" = ":" then
        put string(j) & ":" into char 1 to 3 of line I of field "QuestionTextBox"
      else
        put " " before line I of field "QuestionTextBox"
        put string(j) & ":" into char 1 to 3 of line I of field "QuestionTextBox"
      end if
    end if
    set the foreColor of line I of field "QuestionTextBox" to givTextHiliteColor
  end repeat
  updateStage()
end

on QuestionListSelectAll
  global givState
  if (the activeMonitor of givState = 3) and (the mode of givState = #play) then
    nothing()
    exit
  end if
  set the questionSelectList of givState to []
  repeat with I = 1 to count(GetMonitorListByNumber(the activeMonitor of givState))
    append(the questionSelectList of givState, I)
  end repeat
  DisplayFromList()
end

on QuestionListSelectNone
  global givState
  if (the activeMonitor of givState = 3) and (the mode of givState = #play) then
    nothing()
    exit
  end if
  set the questionSelectList of givState to []
  DisplayFromList()
end

on BuildEditListText
  global givAthleteNameList, givGuestStarList, givState
  set the text of field "EditListBuild" to " "
  if the userTitle of givState = EMPTY then
    set the text of field "EditListBuild" to "Awesome Athletes" & RETURN
  else
    set the text of field "EditListBuild" to the userTitle of givState & RETURN
  end if
  set givGuestStarList to []
  repeat with I = 1 to count(the editList of givState)
    set clipID to getAt(the editList of givState, I)
    if (char 1 to 2 of clipID = "QA") or (char 1 to 2 of clipID = "AV") then
      set athID to char 3 to 5 of clipID
      if getPos(givGuestStarList, item 1 of getaProp(givAthleteNameList, athID)) = 0 then
        append(givGuestStarList, item 1 of getaProp(givAthleteNameList, athID))
      end if
    end if
  end repeat
  MessagePut("Guest Stars found:" && givGuestStarList)
  if count(givGuestStarList) = 0 then
    nothing()
  else
    put "         Guest Starring" & RETURN after field "EditListBuild"
    repeat with I = 1 to count(givGuestStarList)
      put string(getAt(givGuestStarList, I) & RETURN) after field "EditListBuild"
    end repeat
  end if
end